(comment) @comment

[
  (string)
  (multiline_string)
  (character)
] @string

[
  (integer)
  (float)
] @value.number

[
  "true"
  "false"
] @value.boolean

[
  "null"
  "undefined"
  "unreachable"
] @value.null

(builtin_type) @identifier.type
(builtin_identifier) @identifier.core

((builtin_identifier) @processing
  (#match? @processing "^@(import|cImport)$"))

((identifier) @identifier.core
  (#eq? @identifier.core "_"))

(parameter
  name: (identifier) @identifier.argument)

(payload
  (identifier) @identifier.argument)

(field_expression
  member: (identifier) @identifier.property)

(field_initializer
  (identifier) @identifier.property)

(function_declaration
  name: (identifier) @identifier.function)

(call_expression
  function: (identifier) @identifier.function)

(call_expression
  function: (field_expression
    member: (identifier) @identifier.function))

((identifier) @identifier.type
  (#match? @identifier.type "^[A-Z][A-Za-z0-9_]*$"))

((identifier) @identifier.constant
  (#match? @identifier.constant "^[A-Z][A-Z0-9_]+$"))

[
  "asm"
  "const"
  "defer"
  "errdefer"
  "error"
  "return"
  "test"
  "var"
] @keyword

[
  "struct"
  "union"
  "enum"
  "opaque"
  "fn"
] @keyword.construct

[
  "if"
  "else"
  "switch"
  "for"
  "while"
  "try"
  "catch"
  "break"
  "continue"
] @keyword.condition

[
  "usingnamespace"
  "export"
  "comptime"
  "inline"
  "noinline"
  "extern"
  "pub"
  "packed"
  "threadlocal"
  "volatile"
  "allowzero"
  "noalias"
  "addrspace"
  "align"
  "callconv"
  "linksection"
  "async"
  "await"
  "suspend"
  "nosuspend"
  "resume"
] @keyword.modifier

[
  "and"
  "or"
  "orelse"
] @keyword.operator

(ERROR) @invalid